diff --git a/tests/pss/colpitt_osc_pss.cir b/tests/pss/colpitt_osc_pss.cir
new file mode 100644
index 000000000..c3aac58b5
--- /dev/null
+++ b/tests/pss/colpitt_osc_pss.cir
@@ -0,0 +1,22 @@
+Colpitt's Oscillator Circuit
+* Colpitt is an harmonic oscillator (LC based) which use
+* a capacitive partition of resonator to feed the single 
+* active device.
+* Prediceted frequency is about 3.33945e+06 Hz.
+
+* Models:
+.model qnl npn(level=1 bf=80 rb=100 ccs=2pf tf=0.3ns tr=6ns cje=3pf cjc=2pf va=50)
+
+r1 	1 0 	1
+q1 	2 1 3	qnl
+vcc 	4 0 	5
+rl 	4 2 	750
+c1 	2 3 	500p
+c2 	4 3 	4500p
+l1 	4 2 	5uH
+re 	3 6 	4.65k
+vee 	6 0 	dc -10 pwl 0 0 1e-9 -10 
+
+*.tran 30n 12u
+.pss 4e6 500e-6 3 1024 11 uic 50 5e-3
+
diff --git a/tests/pss/compl_cross_quad_osc_pss.cir b/tests/pss/compl_cross_quad_osc_pss.cir
new file mode 100644
index 000000000..5f4072061
--- /dev/null
+++ b/tests/pss/compl_cross_quad_osc_pss.cir
@@ -0,0 +1,33 @@
+Complimentary Cross Quad CMOS Oscillator
+* Predicted frequency is 5.59197e+08 Hz.
+
+* Supply
+vdd	vdd	gnd	1.2 pwl 0 1.2 1e-9 1.2
+rdd	vdd	vdd_ana	70m
+rgnd	gnd	gnd_ana	70m
+
+* Cross quad
+mpsx	v_plus	v_minus	vdd_ana	vdd_ana	pch	w=10u l=0.1u
+mnsx	v_plus	v_minus	gnd_ana	gnd_ana	nch	w=10u l=0.1u
+mpdx	v_minus	v_plus	vdd_ana	vdd_ana	pch	w=10u l=0.1u
+mndx	v_minus	v_plus	gnd_ana	gnd_ana	nch	w=10u l=0.1u
+
+* Lumped elements model of real inductor
+ls	v_plus	i1	19.462n	ic=0.06
+rs	i1	v_minus	7.789
+cs	v_plus	v_minus	443f
+coxs	v_plus	is	2.178p
+coxd	v_minus	id	2.178p
+rsis	is	gnd_ana	308
+rsid	id	gnd_ana	308
+csis	is	gnd_ana	51f
+csid	id	gnd_ana	51f
+
+* Parallel capacitor to determine leading resonance
+cp	v_plus	v_minus	3.4p
+
+.model nch nmos ( version=4.4 level=54 lmin=0.1u lmax=20u wmin=0.1u wmax=10u  )
+.model pch pmos ( version=4.4 level=54 lmin=0.1u lmax=20u wmin=0.1u wmax=10u  )
+
+*.tran 0.05n 1u uic
+.pss 624e6 1u v_plus 1024 10 uic 50 5e-3
diff --git a/tests/pss/hartley_osc_pss.cir b/tests/pss/hartley_osc_pss.cir
new file mode 100644
index 000000000..8e867c1e8
--- /dev/null
+++ b/tests/pss/hartley_osc_pss.cir
@@ -0,0 +1,19 @@
+Hartley's Oscillator Circuit
+* Hartley is an harmonic oscillator (LC based) which use
+* an inductive partition of resonator to feed the single 
+* active device. Output is taken on node 2.
+* Prediceted frequency is about 122.06 Hz.
+
+* Models:
+.model qnl npn(level=1 bf=80 rb=100 ccs=2pf tf=0.3ns tr=6ns cje=3pf cjc=2pf va=50)
+
+vcc 	1 0 	5 pwl 0 0 1e-5 5
+r1	1 2	0.2k
+q1	2 3 0	qnl
+c1	3 4	633n
+l1	3 0	1.5
+l2	0 4	500m
+r2	4 2	100
+
+*.tran 300n 50m
+.pss 150 200e-3 2 1024 11 uic 50 5e-3
diff --git a/tests/pss/ring_osc_pss.cir b/tests/pss/ring_osc_pss.cir
new file mode 100644
index 000000000..3832f6451
--- /dev/null
+++ b/tests/pss/ring_osc_pss.cir
@@ -0,0 +1,26 @@
+Ring CMOS Oscillator
+* Predicted frequency is 3.84841e+09 Hz.
+
+* Supply
+vdd	vdd	gnd	1.2 pwl 0 1.2 1e-9 1.2
+rdd	vdd	vdd_ana	70m
+rgnd	gnd	gnd_ana	70m
+
+* Inverter
+mp1	inv1	inv3	vdd_ana vdd_ana	pch	w=10u l=0.18u
+mn1	inv1	inv3	gnd_ana	gnd_ana	nch	w=10u l=0.18u
+mp2	inv2	inv1	vdd_ana	vdd_ana	pch	w=10u l=0.18u
+mn2	inv2	inv1	gnd_ana	gnd_ana	nch	w=10u l=0.18u
+mp3	inv3	inv2	vdd_ana	vdd_ana	pch	w=10u l=0.18u
+mn3	inv3	inv2	gnd_ana	gnd_ana	nch	w=10u l=0.18u
+
+* Buffer out
+mp4	bout	inv3	vdd_ana	vdd_ana	pch	w=10u l=0.18u
+mn4	bout	inv3	gnd_ana	gnd_ana	nch	w=10u l=0.18u
+
+.model nch nmos ( version=4.4 level=54 lmin=0.1u lmax=20u wmin=0.1u wmax=10u  )
+.model pch pmos ( version=4.4 level=54 lmin=0.1u lmax=20u wmin=0.1u wmax=10u  )
+
+*.tran 0.005n 100n
+*.plot tran v(4)
+.pss 624e6 500n bout 1024 10 uic 100 5e-3
diff --git a/tests/pss/vackar_osc_pss.cir b/tests/pss/vackar_osc_pss.cir
new file mode 100644
index 000000000..5552e950f
--- /dev/null
+++ b/tests/pss/vackar_osc_pss.cir
@@ -0,0 +1,21 @@
+Vackar's Oscillator Circuit
+* Vackar is a derivation of Colpitt's oscillator (LC based).
+* Oscillation is taken on node 4.
+* Predicted frequency is 1.92291e+06Hz.
+
+* Models:
+.model qnl npn(level=1 bf=80 rb=100 ccs=2pf tf=0.3ns tr=6ns cje=3pf cjc=2pf va=50)
+
+vcc 	1 0 	5 pwl 0 10 1e-9 5
+lrfc	1 2	100u
+cdec	2 0	7n
+q1 	3 2 0	qnl	
+rb 	3 0 	4700
+c1 	3 4 	100p
+c2 	3 0 	600p
+c0	4 0	1n
+l1 	4 1 	6.2u
+
+*.tran 30n 12u
+*.plot tran v(4)
+.pss 4e6 10e-6 4 1024 10 uic 50 5e-3
diff --git a/tests/pss/vdp_osc_pss.cir b/tests/pss/vdp_osc_pss.cir
new file mode 100644
index 000000000..fd46bede1
--- /dev/null
+++ b/tests/pss/vdp_osc_pss.cir
@@ -0,0 +1,17 @@
+Van Der Pol Oscillator
+* Prediceted frequency is about 4.58957e+06 Hz.
+
+* Third harmonic is high as the first one
+Ba	gib 0	I=-1e-2*v(gib,0)+1e-2*v(gib,0)^3
+* Q is about 10
+La	gib 0	1.2e-6
+Ra	gib 0	158.113
+Ca	gib 0	1e-9 ic=0.5
+*La	gib 0	1e-9
+*Ra	gib 0	474.6
+*Ca	gib 0	1e-9 ic=0.5
+* Ghost node... Test for my PSS!
+Rb	bad 0	1k
+
+*.tran 1e-9 150e-6 uic
+.pss 0.8e6 130e-6 gib 1024 11 uic 50 5e-3